一日一膳腹八分目

llSetCameraEyeOffset(<-5.0,0.0,1.0>); //座った時のカメラの位置を指定します。
llSetCameraAtOffset(<2.0,0.0,0.0>); //座った時にカメラが見ている位置を指定します。

１）座る
２）スロットルを上げて飛ぶ
３）チャットに「c」と入れてカメラを好きな状態にする
４）飛び回る

パイロットが座ったらllListenをチャンネルゼロ（普通のチャット）で唱える。
その時、パイロットだけを聴く対象にする。

１）座る
２）座ったパイロットの発言を聞けるようにllListenを唱える
３）チャットで「c」が聞こえた（listenイベントが発生して発言が「c」だった）らカメラを何かする

changed(integer change)
{
//プリムやスクリプトに状態変化があった場合のイベント
if (change & CHANGED_LINK)
{
//リンクが変更になった
key _av=llAvatarOnSitTarget(); //座っているアバターのＵＵＩＤを取得します。
if (_av!=NULL_KEY) //NULL_KEYでない⇒誰かが座っている。
{
if (pilot==NULL_KEY) //pilotがNULL_KEY⇒誰かが初めて座った。
{
pilot=_av; //pilotに座った人のＵＵＩＤを設定
llRequestPermissions(pilot,PERMISSION_CONTROL_CAMERA | PERMISSION_TAKE_CONTROLS); //カメラ操作とパイロットのキーやマウス操作の監視の権限を要求します
llListenRemove(handle); //追加：今まで聞いていたかもしれないListenをやめます。
handle=llListen(0,"",pilot,""); //追加：パイロットのチャット発言の傍受を開始します。
}
}
else //座っているアバターのＵＵＩＤがNULL_KEYなら誰かが立ち上がったか、または最初から座っていません。
{
init();
}
}
}
listen(integer channel, string name, key id, string message)
{
string _command=llToLower(message); //半角アルファベットをすべて小文字にします
if (_command=="c" || _command=="ｃ" || _command=="Ｃ")
{
//コマンド”Ｃ”。飛行機では一般的にこのコマンドはカメラ操作に割り当てられます。
//ここで何かカメラを操作するか変更します
}
}

llRequestPermissions(pilot,PERMISSION_CONTROL_CAMERA | PERMISSION_TAKE_CONTROLS);

listen(integer channel, string name, key id, string message)
{
string _command=llToLower(message); //半角アルファベットをすべて小文字にします
if (_command=="c" || _command=="ｃ" || _command=="Ｃ")
{
//コマンド”Ｃ”。飛行機では一般的にこのコマンドはカメラ操作に割り当てられます。
camon=!camon; //カメラ状態を現在と逆にします。
setCamera(); //カメラ状態を反映させます。
}
}

//-----------------------------------------
//動的カメラ設定関数 setCamera()
//-----------------------------------------
integer camon=FALSE; //カメラタイプ
setCamera()
{
if (camon)
{
//camonがTRUE⇒カメラコントロールあり
if ((llGetPermissions() & PERMISSION_CONTROL_CAMERA) && llGetAgentSize(pilot)!=ZERO_VECTOR) //パイロットがいて、カメラコントロールがある場合だけ制御開始します。
{
list _rules=[
CAMERA_ACTIVE,TRUE,
CAMERA_BEHINDNESS_ANGLE ,0.0,
CAMERA_BEHINDNESS_LAG,0.3,
CAMERA_FOCUS_LAG,0.3,
CAMERA_FOCUS_THRESHOLD,0.0,
CAMERA_DISTANCE,3.0,
CAMERA_PITCH,5.0,
CAMERA_FOCUS_LOCKED, FALSE,
CAMERA_POSITION_LAG,0.6,
CAMERA_POSITION_THRESHOLD,0.0,
CAMERA_FOCUS_OFFSET,<0,0,0>
];
llClearCameraParams();
llSetCameraParams(_rules);
}
}
else
{
//camonがFALSE⇒コントロールなし
llClearCameraParams();
}
}

key pilot=NULL_KEY; //パイロットのＵＵＩＤ
float throttle=0.0; //スロットル状態
vector angular_motor=ZERO_VECTOR; //舵操作状態
integer handle=0; //チャット傍受識別番号
integer camon=FALSE; //カメラタイプ
//-----------------------------------------
//初期化関数 init()
//-----------------------------------------
init()
{
llListenRemove(handle); //チャット傍受を解除します。
pilot=NULL_KEY; //pilotを初期化します。
llSetStatus(STATUS_PHYSICS,FALSE); //物理を切ってその場に停止させます。
camon=FALSE; //カメラタイプを初期化します。
}
//-----------------------------------------
//エンジン設定関数 planeEngine()
//-----------------------------------------
planeEngine()
{
llSetVehicleType(VEHICLE_TYPE_AIRPLANE); //乗り物タイプを飛行機にします。
llSetVehicleFloatParam( VEHICLE_ANGULAR_MOTOR_TIMESCALE,0.0); //舵操作への反応速度を最高感度にします。
}
//-----------------------------------------
//動的カメラ設定関数 setCamera()
//-----------------------------------------
setCamera()
{
if (camon)
{
//camonがTRUE⇒カメラコントロールあり
if ((llGetPermissions() & PERMISSION_CONTROL_CAMERA) && llGetAgentSize(pilot)!=ZERO_VECTOR) //パイロットがいて、カメラコントロールがある場合だけ制御開始します。
{
list _rules=[
CAMERA_ACTIVE,TRUE,
CAMERA_BEHINDNESS_ANGLE ,0.0,
CAMERA_BEHINDNESS_LAG,0.3,
CAMERA_FOCUS_LAG,0.3,
CAMERA_FOCUS_THRESHOLD,0.0,
CAMERA_DISTANCE,3.0,
CAMERA_PITCH,5.0,
CAMERA_FOCUS_LOCKED, FALSE,
CAMERA_POSITION_LAG,0.6,
CAMERA_POSITION_THRESHOLD,0.0,
CAMERA_FOCUS_OFFSET,<0,0,0>
];
llClearCameraParams();
llSetCameraParams(_rules);
}
}
else
{
//camonがFALSE⇒コントロールなし
llClearCameraParams();
}
}
default
{
state_entry()
{
//初期化イベント
llSitTarget(<0.0,0.0,0.5>,ZERO_ROTATION); //アバターの座る位置
llSetClickAction(CLICK_ACTION_SIT); //クリックしたときの動作を「座る」にします。
llSetCameraEyeOffset(<-5.0,0.0,1.0>); //座った時のカメラの位置を指定します。
llSetCameraAtOffset(<2.0,0.0,0.0>); //座った時にカメラが見ている位置を指定します。
llSetStatus(STATUS_PHYSICS,FALSE); //物理をオフにします。
planeEngine();
}
on_rez(integer start_param)
{
init();
}
changed(integer change)
{
//プリムやスクリプトに状態変化があった場合のイベント
if (change & CHANGED_LINK)
{
//リンクが変更になった
key _av=llAvatarOnSitTarget(); //座っているアバターのＵＵＩＤを取得します。
if (_av!=NULL_KEY) //NULL_KEYでない⇒誰かが座っている。
{
if (pilot==NULL_KEY) //pilotがNULL_KEY⇒誰かが初めて座った。
{
pilot=_av; //pilotに座った人のＵＵＩＤを設定
llRequestPermissions(pilot,PERMISSION_CONTROL_CAMERA | PERMISSION_TAKE_CONTROLS); //カメラ操作とパイロットのキーやマウス操作の監視の権限を要求します
llListenRemove(handle); //今まで聞いていたかもしれないListenをやめます。
handle=llListen(0,"",pilot,""); //パイロットのチャット発言の傍受を開始します。
}
}
else //座っているアバターのＵＵＩＤがNULL_KEYなら誰かが立ち上がったか、または最初から座っていません。
{
init();
}
}
}
run_time_permissions(integer permissions)
{
//権限が許可または不許可であった場合に発生するイベント
if (permissions & PERMISSION_TAKE_CONTROLS) //アバターがキーやマウス操作の監視を許可した場合
{
//各種のキー操作の監視と、通常の動作の停止を要求します
llTakeControls(CONTROL_UP | CONTROL_DOWN | CONTROL_FWD | CONTROL_BACK | CONTROL_RIGHT | CONTROL_LEFT | CONTROL_ROT_RIGHT | CONTROL_ROT_LEFT | CONTROL_ML_LBUTTON | CONTROL_LBUTTON, TRUE, FALSE);
llSetStatus(STATUS_PHYSICS,TRUE); //物理をオンにします。
}
if (permissions & PERMISSION_CONTROL_CAMERA) //アバターがカメラコントロールを許可した場合
{
setCamera(); //カメラ状態を反映させます。（初期値は操作なし）
}
}
listen(integer channel, string name, key id, string message)
{
string _command=llToLower(message); //半角アルファベットをすべて小文字にします
if (_command=="c" || _command=="ｃ" || _command=="Ｃ")
{
//コマンド”Ｃ”。飛行機では一般的にこのコマンドはカメラ操作に割り当てられます。
camon=!camon; //カメラ状態を現在と逆にします。
setCamera(); //カメラ状態を反映させます。
}
}
control(key name, integer keyPress, integer edges)
{
//llTakeControls()で要求したキー・マウス操作が行われた場合に発生するイベント
integer _keyDown=keyPress & edges; //押されているキーのうちで状態が変ったキーは今押され始めたキーです。keyPressとedgesのビット論理和（AND）を取ると取得できます。
integer _keyUp=~keyPress & edges; //押されているキーの逆のうちで状態が変ったキーは今離されたキーです。keyPressのビット反転とedgesのANDを取ると取得できます。


//--------------------------------------------------------
//スロットル（前進速度）
//PgUp（CONTROL_UP）で増速、PgDwn（CONTROL_DOWN）で減速します。
//--------------------------------------------------------
if (keyPress & CONTROL_UP) throttle=throttle+0.01; //この書き方もできるし。。
if (keyPress & CONTROL_DOWN) throttle-=0.01; //この書き方も出来ます。
if (throttle>1.0) throttle=1.0; //最大を超えそうなら最大にします。
else if (throttle<0.0) throttle=0.0; //最少を下回りそうなら最小にします。

//--------------------------------------------------------
//エルロン（ロール・左右傾斜）
//←→キー（CONTROL_ROT_LEFT/CONTROL_ROT_RIGHT）で操作します。
//--------------------------------------------------------
if (keyPress & CONTROL_ROT_LEFT) angular_motor.x-=0.1;
if (keyPress & CONTROL_ROT_RIGHT) angular_motor.x+=0.1;
if (_keyUp & CONTROL_ROT_LEFT) angular_motor.x=0.0; //飛行機では通常、キーを離したらならすぐに回転力をゼロにリセットします。
if (_keyUp & CONTROL_ROT_RIGHT) angular_motor.x=0.0;
if (angular_motor.x>1.0) angular_motor.x=1.0; //最大を超えそうなら最大にします。
else if (angular_motor.x<-1.0) angular_motor.x=-1.0; //最少を下回りそうなら最小にします。

//--------------------------------------------------------
//エレベーター（ピッチ・上下首ふり、水平尾翼）
//↑↓キー（CONTROL_FWD/CONTROL_BACK）で操作します。
//飛行機スクリプトでは慣習的に↑キーで機首下げです。
//↓キーで機首上げです。
//--------------------------------------------------------
if (keyPress & CONTROL_FWD) angular_motor.y+=0.1;
if (keyPress & CONTROL_BACK) angular_motor.y-=0.1;
if (_keyUp & CONTROL_FWD) angular_motor.y=0.0;
if (_keyUp & CONTROL_BACK) angular_motor.y=0.0;
if (angular_motor.y>1.0) angular_motor.y=1.0; //最大を超えそうなら最大にします。
else if (angular_motor.y<-1.0) angular_motor.y=-1.0; //最少を下回りそうなら最小にします。

//--------------------------------------------------------
//ラダー（ヨー・左右首ふり、垂直尾翼）
//SHIFT+←→キー（CONTROL_LEFT/CONTROL_RIGHT）で操作します。
//--------------------------------------------------------
if (keyPress & CONTROL_LEFT) angular_motor.z+=0.1;
if (keyPress & CONTROL_RIGHT) angular_motor.z-=0.1;
if (_keyUp & CONTROL_LEFT) angular_motor.z=0.0;
if (_keyUp & CONTROL_RIGHT) angular_motor.z=0.0;
if (angular_motor.z>1.0) angular_motor.z=1.0; //最大を超えそうなら最大にします。
else if (angular_motor.z<-1.0) angular_motor.z=-1.0; //最少を下回りそうなら最小にします。

llSetForce(<0.0,0.0,llGetMass()*9.8*throttle>,TRUE); //揚力を設定
//速度の最大値を27.0m/sで、それに0.0～1.0をかけて設定します。
llSetVehicleVectorParam(VEHICLE_LINEAR_MOTOR_DIRECTION,<27.0*throttle,0.0,0.0>);
//ロール、ピッチ、ヨー回転にそれぞれ最大値に現在の状態をかけて設定します。
llSetVehicleVectorParam(VEHICLE_ANGULAR_MOTOR_DIRECTION,<10.0*angular_motor.x,1.0*angular_motor.y,0.5*angular_motor.z>);
}
}